plugins {
    id 'fabric-loom' version '1.7-SNAPSHOT' apply false
    id 'maven-publish'
}

subprojects {
    apply plugin: 'fabric-loom'
    apply plugin: 'maven-publish'
    apply plugin: 'java'

    version = project.mod_version
    group = project.maven_group

    repositories {
        maven { url "https://maven.terraformersmc.com/releases/" } 
    }

    dependencies {
        minecraft "com.mojang:minecraft:${project.minecraft_version}"
        mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
        modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    }

    processResources {
        inputs.property "version", project.version
        inputs.property "minecraft_version", project.minecraft_version
        inputs.property "minecraft_range", project.minecraft_range
        inputs.property "loader_version", project.loader_version
        filteringCharset "UTF-8"

        filesMatching("fabric.mod.json") {
            expand "version": project.version,
                   "minecraft_version": project.minecraft_version,
                   "minecraft_range": project.minecraft_range,
                   "loader_version": project.loader_version
        }
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.encoding = "UTF-8"
        // Java version will be configured in individual subprojects
        // if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        //     it.options.release.set(targetJavaVersion)
        // }
    }

    java {
        withSourcesJar()
    }

    jar {
        from("LICENSE") {
            rename { "${it}_${project.archives_base_name}" }
        }
    }
}